本文介紹在ASP網(wǎng)頁應(yīng)用中防止用戶在當(dāng)前會話期間多次提交同一表單的一個簡單方法。它主要由四個子程序組成，在較為簡單的應(yīng)用場合，你只要將這些代碼放在包含文件中直接引用即可；對于那些較為復(fù)雜的環(huán)境，我們在文章的最后給出一些改進(jìn)建議。

　　一、基本工作過程

　　下面我們依次討論這四個子程序。

　　（一）程序初始化

　　這里我們要在Session對象中保存兩個變量，其中：

　　⑴ 每一個表單對應(yīng)一個稱為FID的唯一標(biāo)識，為使該值唯一要用到一個計數(shù)器。

　　⑵ 每當(dāng)一個表單成功提交，必須在一個Dictionary對象中存儲它的FID。

　　我們用一個專用的過程來初始化上述數(shù)據(jù)。雖然以后各個子程序都要調(diào)用它，但實際上每一個會話期間它只執(zhí)行一次：

Sub InitializeFID() 
　　If Not IsObject(Session("FIDList")) Then 
　　Set Session("FIDList")=Server.CreateObject("Scripting.Dictionary") 
　　Session("FID")=0 
　　End If 
　　End Sub

　　（二）生成網(wǎng)頁表單的唯一標(biāo)識符

　　下面這個函數(shù)GenerateFID()用于生成表單的唯一標(biāo)志。該函數(shù)首先將FID值加1，然后返回它：

　　Function GenerateFID() 
　　InitializeFID 
　　Session("FID") = Session("FID") + 1 
　　GenerateFID = Session("FID") 
　　End Function

　　（三）登記網(wǎng)頁已提交表單

　　當(dāng)表單成功地提交時，在Dictionary對象中登記它的唯一標(biāo)識：

　　Sub RegisterFID() 
　　Dim strFID 
　　InitializeFID 
　　strFID = Request("FID") 
　　Session("FIDlist").Add strFID, now() 
　　End Sub

　　（四）檢查網(wǎng)頁表單是否重復(fù)提交

　　在正式處理用戶提交的表單之前，應(yīng)該在Dictionary對象中檢查它的FID是否已經(jīng)登記。下面的CheckFID()函數(shù)用來完成這個工作，如已經(jīng)登記，它返回FALSE，否則返回TRUE:

Function CheckFID() 
　　Dim strFID 
　　InitializeFID 
　　strFID = Request("FID") 
　　CheckFID = not Session("FIDlist").Exists(strFID) 
　　End Function

　　二、如何使用

　　有兩個地方要用到上述函數(shù)，即表單生成時與結(jié)果處理時。假設(shè)上述四個子程序已經(jīng)放入包含文件Forms.inc中，下面的代碼根據(jù)FID值來決定生成表單還是處理表單結(jié)果，它所描述的處理過程適合于大多數(shù)ASP應(yīng)用：

　　＜ %Option Explicit%＞ 
　　＜ !--#include file="forms.inc"--＞ 
　　＜ HTML＞ 
　　＜ HEAD＞ 
　　＜ TITLE＞表單提交測試＜ /TITLE＞ 
　　＜ /HEAD 
　　＜ BODY＞ 
　　＜ % 
　　If Request("FID") = "" Then 
　　GenerateForm 
　　Else 
　　ProcessForm 
　　End If 
　　%＞ 
　　＜ /BODY＞ 
　　＜ /HTML＞

　　GenerateForm負(fù)責(zé)生成表單，表單中應(yīng)該含有一個隱藏的FID，如：

＜ % 
　　Sub GenerateForm() 
　　%＞ 
　　＜ form action="＜ %=Request.ServerVariables("PATH_INFO")%＞" method=GET＞ 
　　＜ input type=hidden name=FID value="＜ %=GenerateFID()%＞"＞ 
　　＜ input type=text name="param1" value=""＞ 
　　＜ input type=submit value="OK"＞ 
　　＜ /form＞ 
　　＜ % 
　　End Sub 
　　%＞

　　ProcessForm負(fù)責(zé)處理通過表單提交的內(nèi)容，但在處理之前應(yīng)該先調(diào)用CheckFID()檢查當(dāng)前表單是否已經(jīng)提交，代碼類如：

　　＜ % 
　　Sub ProcessForm() 
　　If CheckFID() Then 
　　Response.Write "你輸入的內(nèi)容是" & Request.QueryString("param1") 
　　RegisterFID 
　　Else 
　　Response.Write "此表單只能提交一次!" 
　　End If 
　　End Sub 
　　%＞

　　三、限制與改進(jìn)措施

　　上面我們介紹了在當(dāng)前會話期間限制同一表單被多次提交的一種方法。在實際應(yīng)用中可能需要從多方面加以改進(jìn)，例如：

　　⑴ 在登記表單ID之前檢查用戶輸入數(shù)據(jù)的合法性，使得數(shù)據(jù)不合法時用戶可以按“后退”按鈕返回，在修正后再次提交同一表單。

　　⑵ 這種對表單提交的限制最多只能在當(dāng)前會話期間有效。如果要求這種限制能夠跨越多個會話，那么就要用到Cookeis或數(shù)據(jù)庫來保存相關(guān)數(shù)據(jù)了。

　　⑶ 這種方法是不安全的。它僅用于防范誤操作，不能防止熟練用戶有意地多次提交同一表單。

---